Tomasz Grysztar - Flat Assembler 1.64. Мануал программера

• Название: Flat Assembler 1.64. Мануал программера
• Автор: Tomasz Grysztar
• Жанр: Базы данных

---

Символьные константы могут использоваться для адаптации синтаксиса ассемблера к персональным предпочтениям. Например, следующие определения создают удобные ярлыки для всех операторов размера:

b equ byte

w equ word

d equ dword

p equ pword

f equ fword

q equ qword

t equ tword

x equ dqword

Так как символьная константа может так же иметь пустое значение, она может использоваться для того, чтобы допустить синтаксис со словом «offset» перед каким-нибудь значением адреса:

offset equ

После такого определения «mov ax, offset char» будет правильной конструкцией, которая будет копировать смещение переменной «char» в регистр «ax», так как «offset» заменяется пустым значением, и поэтому игнорируется.

Символьные константы могут также быть определены директивой «fix», которая имеет такой же синтаксис, как «equ», но определяет константы высшего приоритета — они заменяются их символическим значением даже перед совершением директив препроцессора и макроинструкций. Исключением является сама директива «fix», которая имеет наивысший возможный приоритет, и поэтому допускает переопределение констант, заданных таким путем. Но если такие константы высшего приоритета находятся внутри значения, следующего за директивой «fix», они заменяются их значениями перед присвоением этого значения новой константе.

Директива «fix» может использоваться для адаптирования директив препроцессора, что нельзя сделать директивой «equ». Например:

incl fix include

определяет короткое имя для директивы «include», тогда как такое же определение директивой «equ» не даст такого результата, так как стандартные символьные константы заменяются на из значения после поиска строк с директивами препроцессора.

2.3.3 Макроинструкции

«macro» позволяет вам определить собственный комплекс инструкций, называемых макроинструкциями. Их использование может существенно упростить процесс программирования. В своей простейшей форме директива похожа на описание символьной константы. Например, следующая строка определяет ярлык для инструкции «test al,0xFF»:

macro tst {test al,0xFF}

После директивы «macro» должно идти имя макроинструкции и далее её содержание, заключенное между знаками «{» и «}». Вы можете использовать инструкцию «tst» в любом месте после её определения и она будет ассемблирована как «test al,0xFF». Определение символьной константы с таким значением даст похожий результат, различие лишь в том, что имя макроинструкции будет распознаваться только как мнемоник инструкции. Также, макроинструкции заменяются соответствующим кодом даже перед заменой символьных констант на их значения. То есть, если вы вы определите макроинструкцию и символьную константу под одним и тем же именем и используете это имя как мнемоник инструкции, оно будет заменено на содержание макроинструкции, но если вы используете его внутри операндов, имя будет заменено на значение символьной константы.

Определение макроинструкции может сотоять из нескольких строк, потому что знаки «{» и «}» не обязательно должны находиться на одной строке директивой «macro». Например:

macro stos0

{

 xor al,al

 stosb

}

Макроинструкция «stos0» будет заменена на эти две инструкции ассемблера, где бы он не использовался.

Как и инструкции, которым требуются несколько операндов, для макроинструкции можно задать требование нескольких аргументов, разделяя их запятыми. Имена этих аргументов должны следовать за именем макроинструкции на строке с директивой «macro». В любом месте в макроинструкции, где эти имена появятся, они будут заменены соостветствующими значениями, указанными там, где макроинструкция используется. Вот пример макроинструкции, которая делает выравнивание данных для двоичного формата вывода:

macro align value { rb (value-1)-($+value-1) mod value }

Когда инструкция «align 4» встречается после этого задания макроинструкции, она заменяется на его содержание, и здесь «value» станет 4, а результат будет «rb (4–1)-($+4–1) mod 4».

Если в определении макроинструкции встречается её же имя, то используется предыдущее значение этого имени. Таким образом могут быть сделаны полезные переопределения макросинструкций, например:

macro mov op1,op2

{

 if op1 in

  & op2 in

  push op2

  pop op1

 else

  mov op1,op2

end if

}

Эта макроинструкция расширяет синтаксис инструкции «mov», позволяя обоим операндам быть сегментными регистрами. Например, «mov ds,es» будет ассемблировано как «push es» и «pop ds». Во всех других случаях будет использована стандартная инструкция «mov». Синтаксис этого «mov» может быть расширен далее определением следующей макроинструкции с таким именем, который будет использовать предыдущий:

macro mov op1,op2,op3

{

 if op3 eq

  mov op1,op2

 else

  mov op1,op2

  mov op2,op3

end if

}

Это позволяет инструкции «mov» иметь три операнда, но она так же все ещё может иметь два операнда, так как если макроинструкции задается меньше аргументов, чем ему требуется, оставшиеся заполняются пустыми значениями. Если заданы три операнда, то макроинструкция превратится в две ранее определенных, то есть «mov es,ds,dx» будет ассемблировано как «push ds», «pop es» и «mov ds,dx».

Если требуется создать макроинструкцию с аргументом, который содержит запятые, этот аргумент следует заключить между «<» и «>». Если он содержит больше одного знака «<», то для окончания его описания должно быть использовано такое же количество «>».

«purge» позволяет отменить последнее определение указанной макроинструкции. За директивой должно следовать одно или больше имен макроинструкций, разделенных запятыми. Если указанная макроинструкция не определена, это не вызовет ошибку. Например, после расширения синтаксиса «mov» вышеуказанными макроинструкциями вы можете отключить синтаксис с тремя операндами, используя директиву «purge mov». Следующее «purge mov» отключит синтаксис для сегментных регистров, а дальнейшее применение этой директивы не возымеет эффекта.

Если после директивы «macro» вы заключаете некоторую группу аргументов в квадратные скобки, это позволит при использовании макроинструкции задать данной группе аргументов больше значений. Любой следующий аргумент данный после последнего аргумента данной группы начнет новую группу и станет её первым членом. Поэтому после закрытия квадратных скобок не должно быть имен аргументов. Содержание макроинструкции будет обрабатываться для каждой такой группы аргументов отдельно. Простейший пример — это заключение одного имени аргумента в квадратные скобки:

macro stoschar [char]

{

 mov al,char

 stosb

}

Эта макроинструкция допускает неограниченное число аргументов, и каждый будет обработан этими двумя инструкциями отдельно. Например, «stoschar 1,2,3» будет ассемблирован как следующие инструкции:

mov al,1

stosb

mov al,2

stosb

mov al,3

stosb

Существуют некоторые специальные директивы, возможные только внутри определений макроинструкций. Директива «local» задает локальные имена, которые будут заменены уникальными значениями каждый раз, когда используется макроинструкция. За ней должны следовать имена, разделенные запятыми. Эта директива обычно требуется для внутренних констант или меток макроинструкции. Например:

macro movstr

{

 local move

 move:

 lodsb

 stosb

 test al,al

 jnz move

}

Каждый раз, когда используется эта макроинструкция, «move» заменяется новым уникальным именем. То есть вы не получите ошибку, это обычный случай, когда метка определяется больше, чем один раз.

«forward», «reverse» и «common» делят макроинструкцию на блоки, каждый из которых обрабатывается после окончания обработки предыдущего. Они различаются в поведении только если макроинструкция поддерживает много групп аргументов. Блок инструкций, следующий за «forward» будет обрабатываться для каждой группы аргументов от первой до последней, как блок по умолчанию (без этих директив). Блок, идущий за «reverse» будет обрабатываться для каждой группы аргументов в обратном порядке — от последней до первой. Блок за директивой «common» обрабатывается лишь один раз, просто для всех групп аргументов. Локальное имя, определенное в одном блоке, доступно во всех следующих блоках при обработке той же группы аргументов. Если оно было определено в блоке «common», оно доступно во всех следующих блоках, независимо от обрабатываемой группы.